वीबीए - संख्याओं के सभी क्रमपरिवर्तन एक सरणी में लिखें

कुछ समय पहले, मेरे पास करने के लिए कुछ भी बेहतर नहीं था और मैंने ठीक वही कोड लिखा था जिसकी आपको तलाश है - https://www.vitoshacademy.com/vba-nested-loops-with-recursion/

इस प्रकार, यदि आप इसे थोड़ा बदलते हैं, _ से बचते हैं और size चर को लूप में डालते हैं, तो यह वांछित परिणाम प्रिंट करता है:

यदि आप c = Array(1, 2) को c = Array(1, 2, 3) में बदलते हैं तो यह सिस्टम में एक तीसरा तत्व जोड़ देगा।

Sub Main()

    Static size         As Long
    Static c            As Variant
    Static arr          As Variant
    Static n            As Long

    c = Array(1, 2)
    n = UBound(c) + 1
    For size = 1 To 4
        ReDim arr(size - 1)
        EmbeddedLoops 0, size, c, n, arr
        Debug.Print "---------"
    Next size

End Sub

Function EmbeddedLoops(index, k, c, n, arr)

    Dim i                   As Variant
    If index >= k Then
        PrintArrayInOneLine arr
    Else
        For Each i In c
            arr(index) = i
            EmbeddedLoops index + 1, k, c, n, arr
        Next i
    End If

End Function

Public Sub PrintArrayInOneLine(myArray As Variant)

    Dim counter     As Long
    Dim sArray      As String
    For counter = LBound(myArray) To UBound(myArray)
        sArray = sArray & myArray(counter)
    Next counter
    Debug.Print sArray

End Sub