मुझे एक समय में घटनाओं के साथ कई बायोमेट्रिक्स उपकरणों के लिए सक्रिय (250+) कनेक्शन बनाने के लिए zkemkeeper.CZKEM के कई उदाहरण बनाने की आवश्यकता है। मैंने अपना वांछित आउटपुट करने के लिए एक वर्ग बनाया:

Public Class ZKEMEventsClass

    Public CZKEM2 As New zkemkeeper.CZKEM
    Public MyNewWrapperClass As MyWrapperClass

    Public Sub AddBioHandler(iDevice As String, iIP As String, iPort As Integer)
        If CZKEM2.Connect_Net(iIP, iPort) Then
            If CZKEM2.RegEvent(1, 65535) = True Then

                MyNewWrapperClass = New MyWrapperClass(iDevice, CZKEM2)

                AddHandler MyNewWrapperClass.AttEventWrapper, AddressOf LogRaised
                MsgBox("Handler successfully registered")
            Else
                MsgBox("Error Registering Events")
            End If
        Else
            MsgBox("Error Connecting to Device")
        End If

    End Sub


    Public Sub RemoveBioHandler(iDevice As String, CZKEM As zkemkeeper.CZKEM)
        >>> MyNewWrapperClass = New MyWrapperClass(iDevice, CZKEM)
        >>> RemoveHandler MyNewWrapperClass.AttEventWrapper, AddressOf LogRaised
    End Sub

    Public Sub LogRaised(ByVal SenderName As String, ByVal sEnrollNumber As String, ByVal iIsInValid As Integer, ByVal iAttState As Integer, ByVal iVerifyMethod As Integer, ByVal iYear As Integer, ByVal iMonth As Integer, ByVal iDay As Integer, ByVal iHour As Integer, ByVal iMinute As Integer, ByVal iSecond As Integer, ByVal iWorkCode As Integer)
        MsgBox("Raised event details here... [EnrollID, Year, Month, Day]...")
    End Sub
End Class

ध्यान दें: मैंने प्रत्येक बायोमेट्रिक्स डिवाइस में कस्टम डिवाइस नाम एम्बेड करने के लिए MyWrapperClass बनाया और उपयोग किया ताकि मैं पहचान सकूं कि कौन सा डिवाइस [जैसे CZKEM2] ने जो कुछ भी उठाया है घटना [जैसे CZKEM2.OnAttTransactionEx]


Public Class MyWrapperClass
    Public Property Name
    Private WithEvents CZKEM As zkemkeeper.CZKEM
    Public Event AttEventWrapper(SenderName As String, sEnrollNumber As String, iIsInValid As Integer, iAttState As Integer, iVerifyMethod As Integer, iYear As Integer, iMonth As Integer, iDay As Integer, iHour As Integer, iMinute As Integer, iSecond As Integer, iWorkcode As Integer)

    Public Sub New(WrapperName As String, CZKEMObject As zkemkeeper.CZKEM)
        Me.Name = WrapperName
        Me.CZKEM = CZKEMObject

    End Sub

    Private Sub HandleEvent(ByVal sEnrollNumber As String, ByVal iIsInValid As Integer, ByVal iAttState As Integer, ByVal iVerifyMethod As Integer, ByVal iYear As Integer, ByVal iMonth As Integer, ByVal iDay As Integer, ByVal iHour As Integer, ByVal iMinute As Integer, ByVal iSecond As Integer, ByVal iWorkCode As Integer) Handles CZKEM.OnAttTransactionEx
        RaiseEvent AttEventWrapper(Me.Name, sEnrollNumber, iIsInValid, iAttState, iVerifyMethod, iYear, iMonth, iDay, iHour, iMinute, iSecond, iWorkCode)
    End Sub
End Class

अपने मुख्य कार्यक्रम में, मैंने नीचे दिए गए कोड का उपयोग किया:

Sub ConnectToDevice()
        Dim iIP As String
        Dim iDevice As String
        Dim iPort As Integer
        For x = 1 To 2
            Select Case x
                Case 1
                    iIP = "122.3.47.43"
                    iDevice = "Device 1"
                Case 2
                    iIP = "192.168.10.201"
                    iDevice = "Device 2"
            End Select


            'This is the section where I create new instance of my ZKEMEventsClass
            Dim NewConnect As New ZKEMEventsClass
            NewConnect.AddBioHandler(iDevice, iIP, iPort)

        Next
End Sub

    Sub Disconnect()
        >>> For Each CZKEMObject As KeyValuePair(Of String, zkemkeeper.CZKEM) In MyWrapperClass.ListOfDevices
            >>> Dim NewRemoveHandler As New ZKEMEventsClass
            >>> NewRemoveHandler.RemoveBioHandler(CZKEMObject.Key, CZKEMObject.Value)
        >>> Next

    End Sub

प्रश्न #1: मैं अपने प्रत्येक ईवेंट हैंडलर को कैसे हटा सकता हूं या जब यह सब मेरी ZKEMEventsClass कक्षा के किसी अन्य उदाहरण से बनाया गया था?

प्रश्न #2 यदि प्रश्न #1 उत्तर देने योग्य नहीं है, तो क्या मेरी आवश्यकताओं को पूरा करने के लिए मेरे लिए अन्य [कार्यशील] विकल्प हैं?

मैं अभी एक हफ्ते के लिए यहां फंस गया हूं, और मुझे Google से मेरी समस्या के समान कुछ भी नहीं मिल रहा है।

कृपया मेरी किसी की मदद करें :(

3
NickNok_27 29 अप्रैल 2019, 09:08

1 उत्तर

सबसे बढ़िया उत्तर

जब आप किसी ईवेंट को हटाना चाहते हैं, तो आप वर्तमान में यही कर रहे हैं:

Public Sub RemoveBioHandler(iDevice As String, CZKEM As zkemkeeper.CZKEM)
     MyNewWrapperClass = New MyWrapperClass(iDevice, CZKEM)
     RemoveHandler MyNewWrapperClass.AttEventWrapper, AddressOf LogRaised
End Sub

आप एक नया ZkemEventClass ऑब्जेक्ट बना रहे हैं (जो एक हैंडलर को इसकी घटना से जोड़ता है क्योंकि आपने इसे कंस्ट्रक्टर में परिभाषित किया है) और फिर आप इस नए बनाए गए ऑब्जेक्ट पर removeBioHandler को कॉल करते हैं, जो सफलतापूर्वक हैंडलर को हटा देता है। लेकिन आपने कभी इस ऑब्जेक्ट का उपयोग नहीं किया है, यह ऑब्जेक्ट वह ऑब्जेक्ट नहीं है जिसे आपने पहले बनाया था और जिसके साथ आप काम कर रहे थे। यह केवल उस उप के भीतर मौजूद है जहां आपने इसे परिभाषित किया है।

अपने मुख्य कार्यक्रम में आपको अपने पास मौजूद प्रत्येक ZKemEventClass ऑब्जेक्ट के संदर्भ को बनाए रखने की आवश्यकता है, और जब इससे छुटकारा पाने का समय आता है, तो आप इसे RemoveBioHandler प्रॉपर्टी कहते हैं। यहां मुख्य बात यह है कि आप उस उसी वस्तु के लिए विधि को कॉल करते हैं। कुछ नव निर्मित नहीं।

जैसा कि आप रैपरक्लास के संदर्भों का एक शब्दकोश रखने के लिए, आप ऐसा कुछ कर सकते हैं:

Public Class MyManagerClass
    Public MyDevicesDictionary As New Dictionary(Of String, MyWrapperClass)

    Public Sub AddDevice(Device As MyWrapperClass)
        MyDevicesDictionary.Add(Device.Name, Device)
        AddHandler Device.AttEventWrapper, AddressOf EventHandlerName
    End Sub


    Public Sub RemoveDevice(DeviceName As String)
        Dim Device As MyWrapperClass = MyDevicesDictionary(DeviceName)
        MyDevicesDictionary.Remove(DeviceName)
        RemoveHandler Device.AttEventWrapper, AddressOf EventHandlerName
    End Sub

    Public Sub EventHandlerName(Name, sEnrollNumber, iIsInValid, iAttState, iVerifyMethod, iYear, iMonth, iDay, iHour, iMinute, iSecond, iWorkCode)
        'do whatever you want to do here
    End Sub
End Class
1
AConfusedSimpleton 29 अप्रैल 2019, 10:34