अपने लक्ष्य को प्राप्त करने के लिए आपके पास कई विकल्प हैं:

1. सबसे आसान तब होता है जब आप अपनी डेटा फ़ाइलों को उसी फ़ोल्डर में रखते हैं जिसमें EXE फ़ाइल होती है। फिर आप पथ को गतिशील रूप से प्राप्त करने के लिए ExtractFilePath(ParamStr(0)) + 'NameOfFile.txt' का उपयोग कर सकते हैं।
   लेकिन अपनी फाइलों को लिखने के प्रति जागरूक रहें। यदि EXE को कहीं C:\Programs (x86) या C:\Programs में रखा गया है, तो आप केवल फाइलों को लिख सकते हैं जब प्रोग्राम एलिवेटेड (व्यवस्थापक अधिकारों के साथ) चलता है! इस समस्या से बचने के लिए, EXE को किसी फ़ोल्डर में सीधे C:\ के नीचे रखें।

2. यदि आप अपनी डेटा फ़ाइलों को किसी अन्य फ़ोल्डर में रखना चाहते हैं, उदा. कहीं AppData में, आप इस कोड का उपयोग कर सकते हैं:

   uses
     SHFolder;
   
   const
     CSIDL_COMMON_APPDATA = $0023;
     CSIDL_MYMUSIC = $000D;
     CSIDL_MYPICTURES = $0027;
     CSIDL_MYVIDEO = $000E;
     CSIDL_PROGRAM_FILES = $0026;
     CSIDL_PROGRAM_FILES_COMMON = $002B;
     CSIDL_SYSTEM = $0025;
     CSIDL_WINDOWS = $0024;
   
   type
     TSpecialFolder = (
       // user folders
       sfUserAppData = CSIDL_APPDATA, // Anwendungsdaten: Ordner zur Ablage von Einstellungen für Anwendungsprogramme
       sfUserCookies = CSIDL_COOKIES, // Cookies
       sfUserDesktop = CSIDL_DESKTOPDIRECTORY, // Desktop
       sfUserDocuments = CSIDL_PERSONAL, // My files
       sfUserFavorites = CSIDL_FAVORITES, 
       sfUserIEHistory = CSIDL_HISTORY, // Internet history
       sfUserIECache = CSIDL_INTERNET_CACHE, // "Temporary Internet Files"
       sfUserLocalAppData = CSIDL_LOCAL_APPDATA,
       sfUserMusic = CSIDL_MYMUSIC, 
       sfUserNethood = CSIDL_NETHOOD, 
       sfUserPictures = CSIDL_MYPICTURES, 
       sfUserPrintHood = CSIDL_PRINTHOOD, 
       sfUserProfile = CSIDL_PROFILE, // User folder C:\Users\<Username>
       sfUserRecent = CSIDL_RECENT, 
       sfUserSendTo = CSIDL_SENDTO,
       sfUserStartMenuPrograms = CSIDL_PROGRAMS, // "Programs" in Startmenue
       sfUserStartMenu = CSIDL_STARTMENU, // Startmenue
       sfUserStartUp = CSIDL_STARTUP, // Startup in Startmenue
       sfUserTemplates = CSIDL_TEMPLATES,
       sfUserVideo = CSIDL_MYVIDEO, 
   
       // All Users folders
       sfCommonAppData = CSIDL_COMMON_APPDATA, 
       sfCommonDesktop = CSIDL_COMMON_DESKTOPDIRECTORY, 
       sfCommonDocuments = CSIDL_COMMON_DOCUMENTS,
       sfCommonFavorites = CSIDL_COMMON_FAVORITES,
       sfCommonFiles = CSIDL_PROGRAM_FILES_COMMON,
       sfCommonMusic = CSIDL_COMMON_MUSIC,
       sfCommonPictures = CSIDL_COMMON_PICTURES,
       sfCommonStartMenuPrograms = CSIDL_COMMON_PROGRAMS, // "Programs" in Startmenue
       sfCommonStartMenu = CSIDL_COMMON_STARTMENU, 
       sfCommonStartUp = CSIDL_COMMON_STARTUP, // Startup in Startmenue
       sfCommonVideo = CSIDL_COMMON_VIDEO,
   
       // system folders
       sfFonts = CSIDL_FONTS, 
       sfProgramFiles = CSIDL_PROGRAM_FILES,
       sfSystem32 = CSIDL_SYSTEM, 
       sfWindows = CSIDL_WINDOWS 
       );
   
   function GetSpecialFolder(const SpecialFolder: TSpecialFolder): string;
   const
     SHGFP_TYPE_CURRENT = 0;
   var
     Path: array [0 .. MAX_PATH] of char;
   begin
     if SUCCEEDED(SHGetFolderPath(0, Ord(SpecialFolder), 0, SHGFP_TYPE_CURRENT, @Path[0])) then
       result := Path
     else
       result := '';
   end;
   

   उदाहरण:

   GetSpecialFolder(sfUserAppData) + 'YourFolder\NameOfFile.txt'
   

यदि इसे केवल पढ़ने के लिए ही एक्सेस किया जाता है, तो आप इसे निष्पादन योग्य में संसाधन के रूप में जोड़ने पर भी विचार कर सकते हैं। जो तब आपको इंस्टॉलर की आवश्यकता के बिना इस निष्पादन योग्य को वितरित करने की अनुमति देगा।

डेल्फी डब्बलर का एक उदाहरण है, लेकिन मुझे यह थोड़ा भ्रमित करने वाला लगा। मैं वैसे भी इससे लिंक (पीडीएफ) करूंगा।

आप उपयोगकर्ता को उस स्थान का चयन करने दे सकते हैं जहां फ़ाइल को सहेजना है। यदि फ़ाइल प्रत्येक व्यक्तिगत उपयोगकर्ता के लिए है या CommonAppData यदि फ़ाइल को विभिन्न उपयोगकर्ताओं के बीच साझा किया जाना है, तो AppData फ़ोल्डर का प्रस्ताव करना।

जब उपयोग डेटा फ़ाइल गंतव्य का चयन करता है, तो आप इसे एक आईएनआई फ़ाइल में सहेज सकते हैं। INI फ़ाइल को उपयोगकर्ता से पूछे बिना, रजिस्ट्री में या AppData फ़ोल्डर या प्रोग्रामडेटा फ़ोल्डर में सहेजी गई INI फ़ाइल में संग्रहीत किया जा सकता है।

यहाँ उन विशेष फ़ोल्डरों पर हाथ पाने के लिए स्रोत कोड का एक टुकड़ा दिया गया है:

const
    SectionWindow            = 'Window';
    SectionData              = 'Data';
    CompanyFolder            = 'YourCompanyName';


constructor TForm1.Create(AOwner: TComponent);
    var
        CommonPath   : array [0..MAX_PATH] of Char;
        LocalPath    : array [0..MAX_PATH] of Char;
        LangFileName : String;
    begin
        SHGetFolderPath(0, CSIDL_COMMON_APPDATA, 0, SHGFP_TYPE_CURRENT, @CommonPath[0]);
        SHGetFolderPath(0, CSIDL_LOCAL_APPDATA,  0, SHGFP_TYPE_CURRENT, @LocalPath[0]);
        FIniSection     := SectionWindow;
        FIniSectionData := SectionData;
        FAppName        := ChangeFileExt(ExtractFileName(Application.ExeName), '');
        FCommonAppData  := IncludeTrailingPathDelimiter(CommonPath) +
                           CompanyFolder + '\' + FAppName + '\';
        FLocalAppData   := IncludeTrailingPathDelimiter(LocalPath) +
                           CompanyFolder + '\' + FAppName + '\';
        FIniFileName    := FLocalAppData + FAppName + '.ini';
        ForceDirectories(FCommonAppData);
        ForceDirectories(FLocalAppData);
        inherited Create(AOwner);
    end;